Cambiar el orden de las entradas del generador bibtex-autokey- *

Pregunta:

Estoy tratando de migrar de Zotero a org-ref, y me quedé atascado al intentar usar el comando doi-utils-add-bibtex-entry-from-doi . Después de leer la sección Generación automática de claves de referencia y buscar en línea, no pudo encontrar una respuesta a esta pregunta. ¿Puedo cambiar el orden de las entradas generadas automáticamente (autor, año, título), por ejemplo, para tener una clave bibtex author_title_year? Gracias de antemano.

Respuesta:

El orden de los componentes de la clave está codificado, por lo que no puede cambiarlos con una opción de usuario. Sin embargo, puede volver a escribir la función para establecer el orden que desee. Debe cargar su función modificada después de la versión original, por lo que su modificación la reemplazará. El siguiente código hace esto:

(eval-after-load "bibtex"
  '(defun bibtex-generate-autokey ()
    (let* ((names (bibtex-autokey-get-names))
           (year (bibtex-autokey-get-year))
           (title (bibtex-autokey-get-title))
           (autokey (concat
                     bibtex-autokey-prefix-string ;; optional prefix string
                     names
                     (unless (or (equal names "")
                                 (equal title ""))
                       "_") ;; string to separate names from title
                     title
                     (unless (or (and (equal names "")
                                      (equal title ""))
                                 (equal year ""))
                       bibtex-autokey-year-title-separator)
                     year)))
      (if bibtex-autokey-before-presentation-function
          (funcall bibtex-autokey-before-presentation-function autokey)
        autokey))))

Leave a Comment

Your email address will not be published. Required fields are marked *

Scroll to Top

web tasarım