buffers – Cambiar la orientación de la ventana dividida, forma más rápida

Pregunta:

Supongamos que tiene dos búferes abiertos así:

------------------------------------
            |                      |
  buffer 1  |        buffer 2      |       
            |                      |
------------------------------------

¿Cuál es la forma más rápida de cambiar los búferes para obtener esto?

------------------------------------
           buffer 1                |
                                   |
------------------------------------
            buffer 2               |
                                   |
------------------------------------

Respuesta:

Aquí hay una definición que haría lo que está buscando:

(defun toggle-window-split ()
  (interactive)
  (if (= (count-windows) 2)
      (let* ((this-win-buffer (window-buffer))
             (next-win-buffer (window-buffer (next-window)))
             (this-win-edges (window-edges (selected-window)))
             (next-win-edges (window-edges (next-window)))
             (this-win-2nd (not (and (<= (car this-win-edges)
                                         (car next-win-edges))
                                     (<= (cadr this-win-edges)
                                         (cadr next-win-edges)))))
             (splitter
              (if (= (car this-win-edges)
                     (car (window-edges (next-window))))
                  'split-window-horizontally
                'split-window-vertically)))
        (delete-other-windows)
        (let ((first-win (selected-window)))
          (funcall splitter)
          (if this-win-2nd (other-window 1))
          (set-window-buffer (selected-window) this-win-buffer)
          (set-window-buffer (next-window) next-win-buffer)
          (select-window first-win)
          (if this-win-2nd (other-window 1))))))

( Copiado descaradamente de Magnars .emacs.d )

Además, si lo vuelve a llamar, volverá a dividir sus ventanas en la orientación vertical original.

Leave a Comment

Your email address will not be published.

Scroll to Top

istanbul avukat

-

web tasarım