advice – Consejos de deja-encuadernado de Emacs

Pregunta:

Me gustaría anular temporalmente una función en un fragmento de código.

Tomemos, por ejemplo, lo siguiente:

(defun nadvice/load-quiet (args)
  (cl-destructuring-bind
      (file &optional noerror nomessage nosuffix must-suffix)
      args
    (list file noerror t nosuffix must-suffix)))

(defun nadvice/idle-require-quiet (old-fun &rest args)
    (advice-add 'load :filter-args #'nadvice/load-quiet)
    (apply old-fun args)
    (advice-remove #'load #'nadvice/load-quiet))

(advice-add 'idle-require-load-next :around #'nadvice/idle-require-quiet)

Lo que no funciona:

  • Esta. Sería mucho más limpio si pudiera evitar habilitar y deshabilitar manualmente los consejos y confiar en la naturaleza de un solo subproceso de Emacs para que se encargue de las cosas.
  • cl-letf no me deja hacer referencia a la función original, por lo que no puedo implementar cosas que normalmente haría :filter-args .
  • cl-flet no puede anular funciones en otras funciones.
  • noflet es un paquete externo, que me gustaría evitar. (También hace mucho más de lo que necesito)

Respuesta:

¿No podría usar (cl-)letf mientras hace referencia a la función original usted mismo?

Algo como esto:

;; Original function
(defun my-fun (arg)
  (message "my-fun (%s)" arg))


;; Standard call
(my-fun "arg") ;; => my-fun (arg)


;; Temporary overriding (more or less like an around advice)
(let ((orig-fun (symbol-function 'my-fun)))
  (letf (((symbol-function 'my-fun)
          (lambda (arg)
            ;; filter arguments
            (funcall orig-fun (concat "modified-" arg)))))
    (my-fun "arg")))
;; => my-fun (modified-arg)


;; The overriding was only temporary
(my-fun "arg") ;; => my-fun (arg)


También puede envolver esto en una macro si planea reutilizarlo:

(defmacro with-advice (args &rest body)
  (declare (indent 1))
  (let ((fun-name (car args))
        (advice   (cadr args))
        (orig-sym (make-symbol "orig")))
    `(cl-letf* ((,orig-sym  (symbol-function ',fun-name))
                ((symbol-function ',fun-name)
                 (lambda (&rest args)
                   (apply ,advice ,orig-sym args))))
       ,@body)))

El ejemplo anterior se puede reescribir de la siguiente manera:

(defun my-fun (arg)
  (message "my-fun (%s)" arg))


(my-fun "my-arg")

(with-advice (my-fun
              (lambda (orig-fun arg)
                (funcall orig-fun (concat "modified-" arg))))
  (my-fun "my-arg"))

(my-fun "my-arg")

Leave a Comment

Your email address will not be published.

Scroll to Top

istanbul avukat

-

web tasarım